mirror of
https://gitlab.kitware.com/cmake/cmake.git
synced 2026-10-12 23:43:59 +03:00
Alexander Neundorf
352fb9ff66
CMakeSystemSpecificInformation.cmake into a separate file, CMakeEclipseCDT4.cmake -if CMAKE_EXTRA_GENERATOR is set, i.e. either CodeBlocks or KDevelop3 or EclipseCDT4, load a matching cmake script file, which can do things specific for this generator - added such files for Eclipse, KDevelop and CodeBlocks, one thing they all do is they try to find the respective IDE and store it in the CMAKE_(KDEVELOP3|CODEBLOCKS|ECLIPSE)_EXECUTABLE variable. This could be used by cmake-gui to open the project it just generated with the gui (not sure this is possible with eclipse). Alex
59 lines
2.5 KiB
CMake
59 lines
2.5 KiB
CMake
|
|
# This file is included by cmGlobalGenerator::EnableLanguage.
|
|
# It is included after the compiler has been determined, so
|
|
# we know things like the compiler name and if the compiler is gnu.
|
|
|
|
# before cmake 2.6 these variables were set in cmMakefile.cxx. This is still
|
|
# done to keep scripts and custom language and compiler modules working.
|
|
# But they are reset here and set again in the platform files for the target
|
|
# platform, so they can be used for testing the target platform instead
|
|
# of testing the host platform.
|
|
SET(APPLE )
|
|
SET(UNIX )
|
|
SET(CYGWIN )
|
|
SET(WIN32 )
|
|
|
|
|
|
# include Generic system information
|
|
INCLUDE(CMakeGenericSystem)
|
|
|
|
# 2. now include SystemName.cmake file to set the system specific information
|
|
SET(CMAKE_SYSTEM_INFO_FILE Platform/${CMAKE_SYSTEM_NAME})
|
|
|
|
INCLUDE(${CMAKE_SYSTEM_INFO_FILE} OPTIONAL RESULT_VARIABLE _INCLUDED_SYSTEM_INFO_FILE)
|
|
|
|
IF(NOT _INCLUDED_SYSTEM_INFO_FILE)
|
|
MESSAGE("System is unknown to cmake, create:\n${CMAKE_SYSTEM_INFO_FILE}"
|
|
" to use this system, please send your config file to "
|
|
"cmake@www.cmake.org so it can be added to cmake")
|
|
IF(EXISTS ${CMAKE_BINARY_DIR}/CMakeCache.txt)
|
|
CONFIGURE_FILE(${CMAKE_BINARY_DIR}/CMakeCache.txt
|
|
${CMAKE_BINARY_DIR}/CopyOfCMakeCache.txt COPYONLY)
|
|
MESSAGE("Your CMakeCache.txt file was copied to CopyOfCMakeCache.txt. "
|
|
"Please send that file to cmake@www.cmake.org.")
|
|
ENDIF(EXISTS ${CMAKE_BINARY_DIR}/CMakeCache.txt)
|
|
ENDIF(NOT _INCLUDED_SYSTEM_INFO_FILE)
|
|
|
|
|
|
# optionally include a file which can do extra-generator specific things, e.g.
|
|
# CMakeEclipseCDT4.cmake asks gcc for the system include dirs for the Eclipse CDT4 generator
|
|
IF(CMAKE_EXTRA_GENERATOR)
|
|
STRING(REPLACE " " "" _CMAKE_EXTRA_GENERATOR_NO_SPACES ${CMAKE_EXTRA_GENERATOR} )
|
|
INCLUDE("CMake${_CMAKE_EXTRA_GENERATOR_NO_SPACES}" OPTIONAL)
|
|
ENDIF(CMAKE_EXTRA_GENERATOR)
|
|
|
|
|
|
# for most systems a module is the same as a shared library
|
|
# so unless the variable CMAKE_MODULE_EXISTS is set just
|
|
# copy the values from the LIBRARY variables
|
|
# this has to be done after the system information has been loaded
|
|
IF(NOT CMAKE_MODULE_EXISTS)
|
|
SET(CMAKE_SHARED_MODULE_PREFIX "${CMAKE_SHARED_LIBRARY_PREFIX}")
|
|
SET(CMAKE_SHARED_MODULE_SUFFIX "${CMAKE_SHARED_LIBRARY_SUFFIX}")
|
|
SET(CMAKE_SHARED_MODULE_RUNTIME_C_FLAG ${CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG})
|
|
SET(CMAKE_SHARED_MODULE_RUNTIME_C_FLAG_SEP ${CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG_SEP})
|
|
ENDIF(NOT CMAKE_MODULE_EXISTS)
|
|
|
|
|
|
SET(CMAKE_SYSTEM_SPECIFIC_INFORMATION_LOADED 1)
|