mirror of
https://gitlab.kitware.com/cmake/cmake.git
synced 2026-09-25 04:09:36 +03:00
Joerg Bornemann
7c3ca57b91
The variable was only set by the GNU-like compiler modules, so AUTOMOC never generated a moc_predefs.h for compilers targeting the MSVC ABI and moc parsed headers without the compiler's predefined macros. MSVC dumps its predefined macros with '/PD', which needs the conforming preprocessor. Require VS 2019 16.8, because 16.7 and older ignore the flag with warning D9002 and emit no macros at all. clang-cl takes '-dM' through '-Xclang'. Both also echo the preprocessed source, so feed them an empty translation unit. clang with the GNU driver is excluded from 'Compiler/GNU' as well when it simulates MSVC, so give it the usual '-dM -E' command there. Fixes: #28093
50 lines
1.6 KiB
CMake
50 lines
1.6 KiB
CMake
set(CMAKE_AUTOGEN_INTERMEDIATE_DIR_STRATEGY FULL CACHE STRING "" FORCE)
|
|
|
|
enable_language(CXX)
|
|
|
|
find_package(Qt${with_qt_version} REQUIRED COMPONENTS Core)
|
|
|
|
set(CMAKE_AUTOMOC ON)
|
|
set(CMAKE_CXX_STANDARD 11)
|
|
set(CMAKE_CXX_EXTENSIONS OFF)
|
|
|
|
add_library(MocPredefs MocPredefs.cxx)
|
|
|
|
if(NOT DEFINED CMAKE_CXX_COMPILER_PREDEFINES_COMMAND)
|
|
# Do not silently skip on toolchains that are expected to provide it.
|
|
if((CMAKE_CXX_COMPILER_ID STREQUAL "MSVC" AND MSVC_VERSION GREATER_EQUAL 1928)
|
|
OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang"
|
|
AND CMAKE_CXX_SIMULATE_ID STREQUAL "MSVC"))
|
|
message(FATAL_ERROR
|
|
"CMAKE_CXX_COMPILER_PREDEFINES_COMMAND is not defined for "
|
|
"${CMAKE_CXX_COMPILER_ID} ${CMAKE_CXX_COMPILER_VERSION}.")
|
|
endif()
|
|
return()
|
|
endif()
|
|
|
|
if(CMAKE_CXX_COMPILER_ID STREQUAL "LCC" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS "1.26")
|
|
return()
|
|
endif()
|
|
|
|
get_property(_isMultiConfig GLOBAL PROPERTY GENERATOR_IS_MULTI_CONFIG)
|
|
if(_isMultiConfig)
|
|
set(moc_predefs_h "moc_predefs_$<CONFIG>.h")
|
|
set(check_dir "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIG>")
|
|
else()
|
|
set(moc_predefs_h "moc_predefs.h")
|
|
set(check_dir "${CMAKE_CURRENT_BINARY_DIR}")
|
|
endif()
|
|
|
|
add_custom_command(TARGET MocPredefs POST_BUILD VERBATIM COMMAND
|
|
${CMAKE_COMMAND}
|
|
-Din=${CMAKE_CURRENT_BINARY_DIR}/MocPredefs_autogen/${moc_predefs_h}
|
|
-Dout=${check_dir}/check_predefs.h
|
|
-P${CMAKE_CURRENT_SOURCE_DIR}/MocPredefs-prefix.cmake
|
|
)
|
|
|
|
add_executable(MocPredefs-check MocPredefs-check.cxx)
|
|
target_include_directories(MocPredefs-check PRIVATE ${check_dir})
|
|
add_dependencies(MocPredefs-check MocPredefs)
|
|
|
|
add_custom_target(MocPredefs-run-check ALL VERBATIM COMMAND MocPredefs-check)
|