Autogen: Add AUTOMOC test for target dependencies forwarding

Adds an AUTOMOC test that tests if dependencies from add_dependencies()
of an ORIGIN target are forwarded to the ORIGIN_autogen target.

Also fixes the AUTOMOC test that tests if dependencies from
target_link_libraries() of an ORIGIN target are forwarded to the
ORIGIN_autogen target. The test now fails in the ORIGIN_autogen build
if SimpleLib wasn't built before.

Tests/QtAutogen/mocDepends/CMakeLists.txt

@@ -16,31 +16,80 @@ endif()
 
 include_directories(${CMAKE_CURRENT_BINARY_DIR})
 
-# -- Test 1 using generated header
-# This tests the dependency of AUTOMOC of mocDepends1 to the generated object.hpp
-add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/object.hpp
-                   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/invalid.hpp.in ${CMAKE_CURRENT_BINARY_DIR}/object.hpp
-                   COMMAND ${CMAKE_COMMAND} -E sleep 3
-                   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/object.hpp.in ${CMAKE_CURRENT_BINARY_DIR}/object.hpp
-                   )
+# -- Test 1: Depend on generated header
+# The ORIGIN_autogen target must depend on the same *GENERATED* source files as
+# the ORIGIN target. This is a requirement to ensure that all files for the
+# ORIGIN target are generated before the ORIGIN_autogen target is built.
+#
+# This tests the dependency of the mocDepends1_autogen target of mocDepends1
+# to the source file test1_object.hpp, which is *GENERATED* by a custom command.
+# If mocDepends1_autogen gets built *before* or in *parallel* to the
+# custom command, the build will fail. That's because test1_object.hpp,
+# which is required by mocDepends1_autogen, is only valid after the
+# custom command has been completed.
+#
+# The sleep seconds artificially increase the build time of the custom command
+# to simulate a slow file generation process that takes longer to run than
+# the build of the mocDepends1_autogen target.
+add_custom_command(
+  OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/test1_object.hpp
+  COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/invalid.hpp.in ${CMAKE_CURRENT_BINARY_DIR}/test1_object.hpp
+  COMMAND ${CMAKE_COMMAND} -E sleep 3
+  COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/object.hpp.in ${CMAKE_CURRENT_BINARY_DIR}/test1_object.hpp)
 
-add_executable(mocDepends1 test1.cpp
-  ${CMAKE_CURRENT_BINARY_DIR}/object.hpp
-)
+add_executable(mocDepends1 test1.cpp ${CMAKE_CURRENT_BINARY_DIR}/test1_object.hpp)
 target_link_libraries(mocDepends1 ${QT_CORE_TARGET})
 set_target_properties(mocDepends1 PROPERTIES AUTOMOC TRUE)
 
-# -- Test 2 using generated library
-# This tests the dependency of AUTOMOC of mocDepends2 to the
-# generated simpleLib.hpp which belongs to a linked library of mocDepends2
-add_custom_command(OUTPUT simpleLib.hpp simpleLib.cpp
-                   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/invalid.hpp.in ${CMAKE_CURRENT_BINARY_DIR}/simpleLib.hpp
-                   COMMAND ${CMAKE_COMMAND} -E sleep 3
-                   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/simpleLib.hpp.in ${CMAKE_CURRENT_BINARY_DIR}/simpleLib.hpp
-                   COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/simpleLib.cpp.in ${CMAKE_CURRENT_BINARY_DIR}/simpleLib.cpp
-                   )
-add_library(SimpleLib STATIC simpleLib.hpp simpleLib.cpp)
+# -- Test 2: Depend on header generating target
+# The ORIGIN_autogen target must depend on the same user defined targets
+# as the ORIGIN target. This is a requirement to ensure that all files for the
+# ORIGIN target are generated before the ORIGIN_autogen target is built.
+#
+# This tests the dependency of the mocDepends2_autogen target of mocDepends2
+# to the utility target mocDepends2Object. If mocDepends2_autogen gets built
+# *before* or in *parallel* to mocDepends2Object, the build will fail. That's
+# because test2_object.hpp, which is required by mocDepends2_autogen,
+# is only valid after the mocDepends2Object build has been completed.
+#
+# The sleep seconds artificially increase the build time of mocDepends2Object
+# to simulate a slow utility target build that takes longer to run than
+# the build of the mocDepends2_autogen target.
+add_custom_target(mocDepends2Object
+  BYPRODUCTS ${CMAKE_CURRENT_BINARY_DIR}/test2_object.hpp
+  COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/invalid.hpp.in ${CMAKE_CURRENT_BINARY_DIR}/test2_object.hpp
+  COMMAND ${CMAKE_COMMAND} -E sleep 3
+  COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/object.hpp.in ${CMAKE_CURRENT_BINARY_DIR}/test2_object.hpp)
 
-add_executable(mocDepends2 test2.cpp )
-target_link_libraries(mocDepends2 SimpleLib ${QT_CORE_TARGET})
+add_executable(mocDepends2 test2.cpp)
+target_link_libraries(mocDepends2 ${QT_CORE_TARGET})
 set_target_properties(mocDepends2 PROPERTIES AUTOMOC TRUE)
+add_dependencies(mocDepends2 mocDepends2Object)
+
+# -- Test 3: Depend on generated linked library
+# The ORIGIN_autogen target must depend on the same linked libraries
+# as the ORIGIN target. This is a requirement to ensure that all files for the
+# ORIGIN target are generated before the ORIGIN_autogen target is built.
+#
+# This tests the dependency of the mocDepends3_autogen target of mocDepends3
+# to the user generated library SimpleLib, which mocDepends3 links to.
+# If mocDepends3_autogen gets built *before* or in *parallel* to SimpleLib,
+# the build will fail. That's because simpleLib.hpp, which is required by
+# mocDepends3_autogen, is only valid after the SimpleLib build has been
+# completed.
+#
+# The sleep seconds artificially increase the build time of SimpleLib
+# to simulate a slow utility library build that takes longer to run than
+# the build of the mocDepends3_autogen target.
+add_custom_command(
+  OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/simpleLib.hpp ${CMAKE_CURRENT_BINARY_DIR}/simpleLib.cpp
+  COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/invalid.hpp.in ${CMAKE_CURRENT_BINARY_DIR}/simpleLib.hpp
+  COMMAND ${CMAKE_COMMAND} -E sleep 3
+  COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/simpleLib.hpp.in ${CMAKE_CURRENT_BINARY_DIR}/simpleLib.hpp
+  COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/simpleLib.cpp.in ${CMAKE_CURRENT_BINARY_DIR}/simpleLib.cpp)
+add_library(SimpleLib STATIC ${CMAKE_CURRENT_BINARY_DIR}/simpleLib.hpp ${CMAKE_CURRENT_BINARY_DIR}/simpleLib.cpp)
+target_link_libraries(SimpleLib ${QT_CORE_TARGET})
+
+add_executable(mocDepends3 test3.cpp)
+target_link_libraries(mocDepends3 SimpleLib ${QT_CORE_TARGET})
+set_target_properties(mocDepends3 PROPERTIES AUTOMOC TRUE)

Tests/QtAutogen/mocDepends/simpleLib.hpp.in

@@ -1,8 +1,11 @@
 #ifndef SIMPLE_LIB_H
 #define SIMPLE_LIB_H
 
-class SimpleLib
+#include <QObject>
+
+class SimpleLib : public QObject
 {
+  Q_OBJECT
 public:
   SimpleLib();
   ~SimpleLib();

Tests/QtAutogen/mocDepends/test1.cpp

@@ -1,9 +1,8 @@
 
-#include "object.hpp"
+#include "test1_object.hpp"
 
 int main()
 {
   Object obj;
-
   return 0;
 }

Tests/QtAutogen/mocDepends/test2.cpp

@@ -1,10 +1,9 @@
 
-#include "test2.hpp"
+#include "moc_test2_object.cpp"
+#include "test2_object.hpp"
 
 int main()
 {
-  SimpleLib obj;
-  LObject lobject;
-
+  Object obj;
   return 0;
 }

Tests/QtAutogen/mocDepends/test3.cpp

@@ -0,0 +1,12 @@
+
+#include "test3.hpp"
+
+int main()
+{
+  SimpleLib libObject;
+  LObject lobject;
+  return 0;
+}
+
+// AUTOMOC the SimpleLib header simpleLib.hpp
+#include "moc_simpleLib.cpp"

Tests/QtAutogen/mocDepends/test3.hpp

@@ -1,5 +1,5 @@
-#ifndef TEST2_HPP
-#define TEST2_HPP
+#ifndef TEST3_HPP
+#define TEST3_HPP
 
 #include "simpleLib.hpp"
 #include <QObject>