#[[

 pip_code_model(<out_var> file0 [file1 ...] [OPTIONS opt0 [opt1 ...] ] [NAME name])

 Generate code model files for source files file0 [file1 ...]

 Options you can see by exec "pip_cmg -h"
 Relative files pathes read from CMAKE_CURRENT_SOURCE_DIR
 You should add ${<out_var>} to your target

 If NAME specified then "<name>.h" and "<name>.cpp" files will be generated instead
 of default "ccm_<PROJECT_NAME>"



 pip_resources(<out_var> file)

 Generate C++ files for resource file
 You should add ${<out_var>} to your target



 pip_translation(<out_var> ts_file)

 Generate *.btf (binary translation file) from *.ts file
 You should add ${<out_var>} to your target and then install it to somewhere
 for later loading in runtime by PITranslator

]]


macro(PIP_EXTRACT_OPTIONS _pip_files _pip_options _name _abs)
	set(${_pip_files})
	set(${_pip_options})
	set(_cur_opt 0)
	foreach(_currentArg ${ARGN})
		if ("x${_currentArg}" STREQUAL "xABSOLUTE")
			set(${_abs} TRUE)
		elseif ("x${_currentArg}" STREQUAL "xOPTIONS")
			set(_cur_opt 1)
		elseif ("x${_currentArg}" STREQUAL "xNAME")
			set(_cur_opt 2)
		elseif (_cur_opt EQUAL 1)
			list(APPEND ${_pip_options} "${_currentArg}")
		elseif (_cur_opt EQUAL 2)
			set(${_name} "${_currentArg}")
			set(_cur_opt 0)
		else()
			list(APPEND ${_pip_files} "${_currentArg}")
		endif()
	endforeach()
endmacro()


macro(pip_code_model RESULT)
	set(_name "ccm_${PROJECT_NAME}")
	PIP_EXTRACT_OPTIONS(CCM_SRC OPTS _name ABS ${ARGN})
	#message(STATUS "src = ${CCM_SRC}")
	#message(STATUS "result = ${RESULT}")
	#message(STATUS "options = \"${CCM_OPTS}\"")
	set(CMG_INCLUDES)
	foreach(pi ${PIP_INCLUDES})
		list(APPEND CMG_INCLUDES "-I${pi}")
	endforeach()
	set(CCM_OUT ${CMAKE_CURRENT_BINARY_DIR}/${_name}.cpp)
	set(${RESULT} ${${RESULT}} ${CCM_OUT})
	set(CCM_FILES)
	foreach(csrc ${CCM_SRC})
		if (IS_ABSOLUTE "${csrc}")
			list(APPEND CCM_FILES "${csrc}")
		else()
			list(APPEND CCM_FILES "${CMAKE_CURRENT_SOURCE_DIR}/${csrc}")
		endif()
	endforeach()
	#message(STATUS "CCM = ${RESULT}")
	if(NOT DEFINED PIP_DLL_DIR)
		set(PIP_DLL_DIR ${CMAKE_CURRENT_BINARY_DIR})
	endif()
	add_custom_command(OUTPUT ${CCM_OUT}
						COMMAND ${PIP_CMG}
						ARGS -q ${OPTS} -o ${CMAKE_CURRENT_BINARY_DIR}/${_name} ${CMG_INCLUDES} ${CCM_FILES}
						DEPENDS ${CCM_SRC}
						WORKING_DIRECTORY ${PIP_DLL_DIR}
						COMMENT "Generating ${_name}.h, ${_name}.cpp"
						VERBATIM)
endmacro()


macro(pip_resources RESULT INPUT)
	#message(STATUS "src = ${CCM_SRC}")
	#message(STATUS "result = ${RESULT}")
	#message(STATUS "options = \"${CCM_OPTS}\"")
	get_filename_component(RC_OUT "${INPUT}" NAME_WE)
	set(RC_FILE "pirc_${RC_OUT}.cpp")
	set(SRC_RC_OUT "${RC_OUT}")
	set(RC_OUT ${CMAKE_CURRENT_BINARY_DIR}/${RC_FILE})
	set(${RESULT} ${${RESULT}} ${RC_OUT})
	if(IS_ABSOLUTE "${INPUT}")
		set(RC_FILES "${INPUT}")
	else()
		set(RC_FILES "${CMAKE_CURRENT_SOURCE_DIR}/${INPUT}")
	endif()
	#message(STATUS "CCM = ${RESULT}")
	if(NOT DEFINED PIP_DLL_DIR)
		set(PIP_DLL_DIR ${CMAKE_CURRENT_BINARY_DIR})
	endif()
	set(RC_DEPS ${RC_FILES})
	if(NOT BUILDING_pip)
		execute_process(COMMAND "${PIP_RC}" -l -i "${RC_FILES}"
			WORKING_DIRECTORY ${PIP_DLL_DIR}
			OUTPUT_VARIABLE RC_LIST)
		#message("${RC_LIST}")
		string(REPLACE "\n" ";" RC_LIST "${RC_LIST}")
		list(APPEND RC_DEPS "${RC_LIST}")
	endif()
	#message("PIP_RC: ${PIP_RC}")
	#message("RC_OUT: ${RC_OUT}")
	#message("RC_FILES: ${RC_FILES}")
	#message("PIP_DLL_DIR: ${PIP_DLL_DIR}")
	#message("RC_DEPS: ${RC_DEPS}")
	add_custom_command(OUTPUT ${RC_OUT}
		COMMAND ${PIP_RC}
		ARGS -s -i ${RC_FILES} -o ${RC_OUT} -n ${SRC_RC_OUT}
		DEPENDS ${RC_DEPS}
		WORKING_DIRECTORY ${PIP_DLL_DIR}
		COMMENT "Generating ${RC_FILE}"
		VERBATIM)
endmacro()


macro(pip_translation RESULT INPUT)
	#message(STATUS "src = ${CCM_SRC}")
	#message(STATUS "result = ${RESULT}")
	#message(STATUS "options = \"${CCM_OPTS}\"")
	get_filename_component(BTF_FILENAME "${INPUT}" NAME_WE)
	set(BTF_FILENAME "${BTF_FILENAME}.btf")
	set(BTF_OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${BTF_FILENAME})
	list(APPEND ${RESULT} "${BTF_OUTPUT}")
	if(IS_ABSOLUTE "${INPUT}")
		set(IN_FILES "${INPUT}")
	else()
		set(IN_FILES "${CMAKE_CURRENT_SOURCE_DIR}/${INPUT}")
	endif()
	#message(STATUS "CCM = ${RESULT}")
	if(NOT DEFINED PIP_DLL_DIR)
		set(PIP_DLL_DIR ${CMAKE_CURRENT_BINARY_DIR})
	endif()
	#message("PIP_TR: ${PIP_TR}")
	#message("BTF_OUTPUT: ${BTF_OUTPUT}")
	#message("IN_FILES: ${IN_FILES}")
	#message("PIP_DLL_DIR: ${PIP_DLL_DIR}")
	add_custom_command(OUTPUT ${BTF_OUTPUT}
		COMMAND ${PIP_TR}
		ARGS -C -o "${BTF_OUTPUT}" "${IN_FILES}"
		DEPENDS ${IN_FILES}
		WORKING_DIRECTORY ${PIP_DLL_DIR}
		COMMENT "Generating ${BTF_FILENAME}"
		VERBATIM)
endmacro()