cmake_policy(SET CMP0011 NEW) # don`t affect includer policies
#set(_PIP_MODULES pip pip_usb pip_crypt pip_fftw)
if(WIN32)
	find_package(MinGW REQUIRED)
endif()

set(_PIP_INCDIR "${PIP_DIR}/include/pip")
set(_PIP_LIBDIR "${PIP_DIR}/lib")
set(_PIP_BINDIR)
set(_PIP_FP_DP)

if(MINGW_INCLUDE)
	list(APPEND _PIP_INCDIR "${MINGW_INCLUDE}/pip")
	list(APPEND _PIP_LIBDIR "${MINGW_LIB}")
endif()
if(CMAKE_CROSSCOMPILING)
	list(APPEND _PIP_INCDIR "${CMAKE_PREFIX_PATH}/include/pip")
	list(APPEND _PIP_LIBDIR "${CMAKE_PREFIX_PATH}/lib")
else()
	if(NOT WIN32)
		list(APPEND _PIP_INCDIR "/usr/include/pip" "/usr/local/include/pip")
		list(APPEND _PIP_LIBDIR "/usr/lib" "/usr/local/lib")
	endif()
	if(APPLE)
		include_directories(/usr/local/include)
		link_directories(/usr/local/lib)
	endif()
endif()
list(APPEND _PIP_LIBDIR "$ENV{SMSDK_DIR}/lib")

if(MINGW_INCLUDE)
	list(APPEND _PIP_BINDIR "${MINGW_BIN}")
endif()
if(CMAKE_CROSSCOMPILING)
	set(_PIP_FP_DP "NO_DEFAULT_PATH")
	list(APPEND _PIP_BINDIR "/usr/bin" "/usr/local/bin")
else()
	list(APPEND _PIP_BINDIR "${CMAKE_PREFIX_PATH}/bin")
endif()
list(APPEND _PIP_BINDIR "${PIP_DIR}/bin")

find_library(PIP_LIBRARY pip HINTS ${_PIP_LIBDIR})
find_library(PIP_USB_LIBRARY pip_usb HINTS ${_PIP_LIBDIR})
find_library(PIP_CRYPT_LIBRARY pip_crypt HINTS ${_PIP_LIBDIR})
find_library(PIP_FFTW_LIBRARY pip_fftw HINTS ${_PIP_LIBDIR})
find_library(PIP_COMPRESS_LIBRARY pip_compress HINTS ${_PIP_LIBDIR})
find_library(PIP_IO_UTILS_LIBRARY pip_io_utils HINTS ${_PIP_LIBDIR})
find_library(PIP_CONCURRENT_LIBRARY pip_concurrent HINTS ${_PIP_LIBDIR})
find_library(PIP_CLOUD_LIBRARY pip_cloud HINTS ${_PIP_LIBDIR})
find_file(PIP_H_INCLUDE "pip.h" HINTS ${_PIP_INCDIR} $ENV{SMSDK_DIR}/include/pip)
if (DEFINED ANDROID_PLATFORM)
	set(PIP_INCLUDES ${ANDROID_SYSTEM_LIBRARY_PATH}/usr/include/pip)
else()
	get_filename_component(PIP_INCLUDES ${PIP_H_INCLUDE} PATH)
endif()
find_program(PIP_CMG pip_cmg HINTS ${_PIP_BINDIR} ${_PIP_FP_DP})
find_program(PIP_RC pip_rc HINTS ${_PIP_BINDIR} ${_PIP_FP_DP})
if (NOT PIP_LIBRARY)
	message(FATAL_ERROR "Can`t find PIP library!")
endif()
set(_PIP_LIBRARY_PATH_ "${PIP_LIBRARY}")
if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
	find_library(DL_LIBRARY dl)
	list(APPEND PIP_LIBRARY ${DL_LIBRARY})
	if (NOT DEFINED ANDROID_PLATFORM)
		find_library(PTHREAD_LIBRARY pthread)
		find_library(UTIL_LIBRARY util)
		list(APPEND PIP_LIBRARY ${PTHREAD_LIBRARY} ${UTIL_LIBRARY})
	endif()
endif()

if(NOT PIP_VERSION)
	include(CheckSymbolExists)
	check_symbol_exists(PIP_VERSION_NAME "${PIP_INCLUDES}/piversion.h" HAVE_PIP_VERSION)
	if (HAVE_PIP_VERSION)
		file(STRINGS "${PIP_INCLUDES}/piversion.h" _VERSION REGEX "^[ \t]*#define[ \t]+PIP_VERSION_NAME+[ \t]+.*$")
		string(REGEX MATCH "\".*\"" _VERSION ${_VERSION})
		string(LENGTH ${_VERSION} SL)
		math(EXPR SL ${SL}-2)
		string(SUBSTRING ${_VERSION} 1 ${SL} _VERSION)
		set(PIP_VERSION ${_VERSION} CACHE STRING "VERSION")
		if (NOT _PIP_MSG)
			set(_PIP_MSG 1 CACHE BOOL "msg_pip" FORCE)
			message(STATUS "Found PIP: ${_PIP_LIBRARY_PATH_} (version \"${PIP_VERSION}\")")
		endif()
	else()
		message(FATAL_ERROR "Can`t find PIP version file!")
	endif()
endif()
if(PIP_FIND_VERSION VERSION_GREATER PIP_VERSION)
	message(FATAL_ERROR "PIP version ${PIP_VERSION} is available, but ${PIP_FIND_VERSION} requested!")
endif()

include(PIPMacros)